Ayumi电子管模型在Multisim 14.3中不好用？

wjjwb

各位大佬，
这两天想在Multisim 14.3中模拟下胆机，从网上下来Ayumi的模型，管子的特性曲线模拟结果是正常的，然后搭了一个最简单的放大电路，就啥结果也出不来了。
看模拟的时间步长非常的小，不知道是什么原因，做AC扫频的时候报出信息如下：
------ Checking SPICE netlist for Design1 - 2023年1月8日, 17:10:47 ------
======= SPICE Netlist check completed, 0 error(s), 0 warning(s) =======
Error: Unable to converge during the DC operating point calculation. Consider increasing the ABSTOL, VNTOL, and RELTOL options.
Simulation canceled
See convergence help for more information

Ayumi的模型如下：
*
* Generic triode model: ECC88
* Copyright 2003--2008 by Ayumi Nakabayashi, All rights reserved.
* Version 3.10, Generated on Sat Mar  8 22:42:43 2008
*             Plate
*             | Grid
*             | | Cathode
*             | | |
.SUBCKT ECC88 A G K
BGG   GG   0 V=V(G,K)+0.34001426
BM1   M1   0 V=(0.009343174*(URAMP(V(A,K))+1e-10))^-0.49661195
BM2   M2   0 V=(0.75127268*(URAMP(V(GG)+URAMP(V(A,K))/26.621288)+1e-10))^1.9966119
BP    P    0 V=0.007130155*(URAMP(V(GG)+URAMP(V(A,K))/35.434921)+1e-10)^1.5
BIK   IK   0 V=U(V(GG))*V(P)+(1-U(V(GG)))*0.0041180199*V(M1)*V(M2)
BIG   IG   0 V=0.0035650775*URAMP(V(G,K))^1.5*(URAMP(V(G,K))/(URAMP(V(A,K))+URAMP(V(G,K)))*1.2+0.4)
BIAK  A    K I=URAMP(V(IK,IG)-URAMP(V(IK,IG)-(0.0038690245*URAMP(V(A,K))^1.5)))+1e-10*V(A,K)
BIGK  G    K I=V(IG)
* CAPS
CGA   G    A 1.4p
CGK   G    K 3.3p
CAK   A    K 1.8p
.ENDS


有有经验的大佬给指点一下吗？

wjjwb

Ayumi的模型放到LTspice里更离谱，连特性曲线都出不来了，Multisim自带的模型在LTspice里还是正常

wjjwb

刚才把模型中的^替换成**，ltspice里特性曲线出来了。同样的方法在multisim中还是不能模拟除了特性曲线之外的（比如单管的增益）。看来需要转战ltspice了，明天试试在ltspice上试试单管放大。

闭关锁国

这个模型程序需要进行修改才可以使的，做起来有点麻烦。

wjjwb

闭关锁国 发表于 2023-1-9 12:46
这个模型程序需要进行修改才可以使的，做起来有点麻烦。

能麻烦给指个路吗？或者关键词也行。

谢谢

网上搜到diysaudio也有人遇到同样问题，2017年的帖子，最后也没有解决。

闭关锁国

wjjwb 发表于 2023-1-9 19:43
能麻烦给指个路吗？或者关键词也行。

谢谢

给你个改过的，你可以照葫芦画瓢，修改其他管子的模型。

.SUBCKT ECC88 A G K
EGG GG 0 VALUE=V(G,K)+0.34001426
EM1 M1 0 VALUE=(0.009343174*(LIMIT(V(A,K),0,1e16)+1e-10))**-0.49661195
EM2 M2 0 VALUE=(0.75127268*(LIMIT((V(GG)+LIMIT(V(A,K),0,1e16)/26.621288),0,1e16)+1e-10))**1.9966119
EP  P  0 VALUE=0.007130155*(LIMIT((V(GG)+LIMIT(V(A,K),0,1e16)/35.434921),0,1e16)+1e-10)**1.5
EIK IK 0 VALUE=STP(V(GG))*V(P)+(1-STP(V(GG)))*0.0041180199*V(M1)*V(M2)
EIG IG 0 VALUE=0.0035650775*LIMIT(V(G,K),0,1e16)**1.5*(LIMIT(V(G,K),0,1e16)/(LIMIT(V(A,K),0,1e16)+LIMIT(V(G,K),0,1e16))*1.2+0.4)
GIAK A K VALUE=LIMIT(V(IK,IG)-LIMIT(V(IK,IG)-(0.0038690245*LIMIT(V(A,K),0,1e16)**1.5),0,1e16),0,1e16)+1e-10*V(A,K)
GIGK G K VALUE=V(IG)
* CAPS
CGA   G    A 1.4p
CGK   G    K 3.3p
CAK   A    K 1.8p
.ENDS